@echo off
setlocal EnableDelayedExpansion

set Targets=%~1
set VisualStudioVersion=%~2
set Verbosity=%~3
if "%Targets%"=="" goto :DisplayHelp
if "%VisualStudioVersion%"=="" (
  set VisualStudioVersion=15.0
)
if "%Verbosity%"=="" (
  set Verbosity=normal
)

set _MyDir=%~dp0
set _MyDir=%_MyDir:~0,-1%

if "%Targets%"=="-?" goto :DisplayHelp
if "%Targets%"=="-h" goto :DisplayHelp
if "%Targets%"=="--help" goto :DisplayHelp

call FindMSBuild.bat
if not defined MSBuild goto :EOF

set VcpkgEnabled=false

set Continue=1

for %%t IN (%Targets%) do (
  if !Continue!==1 (
    call :BuildTarget %%t
    if errorlevel 1 set Continue=0
  )
)

endlocal
GOTO :EOF

:BuildTarget
  setlocal
  set Target=%~1
  echo BuildTarget building %Target%
  "%MSBuild%" /nologo /property:VisualStudioVersion=%VisualStudioVersion% /verbosity:%Verbosity% /target:%Target% "%_MyDir%\SDKs.proj"
  if errorlevel 1 exit /b 1
  endlocal
  exit /b 0
GOTO :EOF

:DisplayHelp
echo %0 ${Targets} ${VisualStudioVersion} ${Verbosity}
echo.
echo Where
echo   * Targets is a , or ; delimited list of targets to build.
echo   * VisualStudioVersion is 14.0 for Visual Studio 14 2015
echo   or 15.0 for Visual Studio 15 2017.
echo   * Verbosity is q[uiet], m[inimal], n[ormal], d[etailed],
echo   or diag[nostic].
echo.
echo If not specified, the following defaults are used.
echo * VisualStudioVersion: 15.0
echo * Verbosity: normal